Motivation

Parts

• a microcontroller, I'm using Arduino Uno, using other microcontroller may require different pinout.
• some jumper wires, alligator clips, what have you
  
• a solid state relay. This one is a overkill as the current of my components is way below its limit, but it is a safe choice.
  
• some number of immersion water heaters. The number will depend on the size of the container (hence the amount of water that needs to be heated up), the target temperature and room temperature (hence temperature difference), and wattage of the heater.
  
• DS18B20 waterproof one-wire thermometer
  
• some kind of stirring equipment. I use a propeller with a DC motor. There are other choices like submersive water pump.
  
• something to power the microcontroller. I used a 3.5 mm barrel jack power adapter. Noted that the DC motor, LCD screen, and LEDs are all powered by the same source, it's going to drink up some current. 1A is the bare minimum. I may alter the circuit to include another power supply to all these components later. It is always smart to use separate power sources for logic and for components - says the smart Nadya.
  
• a crimper.
  

Circuit design

1. precise temperature control, enabled by the thermometer and the water heater.
   
2. a display that tells me the current temperature reading. It's not super necessary but a nice feature to have. The serial monitor in Arduino IDE could do the same but it required the computer to be connected.
   
3. two LEDs that tells me whether the heater is ON or OFF. This is also not necessary as the LCD screen could already do that, but I like the implication of a status LED and how people use solid-on, blinking, breathing etc. on a single LED to design status indicator.
   
4. water circulation. You can feel with your hand that the water near the water heater is much warmer than the water farther away in the same container. It's going to impact the precision and render the purpose of having a feedback loop pointless.
   

One component at a time

#include <OneWire.h>
#include <DallasTemperature.h>

// Data wire is plugged into port x on the Arduino
#define ONE_WIRE_BUS x

// Setup a oneWire instance to communicate with any OneWire devices (not just Maxim/Dallas temperature ICs)
OneWire oneWire(ONE_WIRE_BUS);

// Pass our oneWire reference to Dallas Temperature. 
DallasTemperature sensors(&oneWire);

void setup(void)
{
  // start serial port
  Serial.begin(9600);
  Serial.println("Dallas Temperature IC Control Library Demo");

  // Start up the library
  sensors.begin();
}

void loop(void)
{ 
  // call sensors.requestTemperatures() to issue a global temperature 
  // request to all devices on the bus
  Serial.print("Requesting temperatures...");
  sensors.requestTemperatures(); // Send the command to get temperatures
  Serial.println("DONE");
  
  Serial.print("Temperature for the device 1 (index 0) is: ");
  Serial.println(sensors.getTempCByIndex(0));  
}

/*
hello! i'm danli, i wrote this firmware to operate my slow cooker!
any questions should be addressed to danlil at uw dot edu
 */
#include <OneWire.h>
#include <DallasTemperature.h>
// include the library code:
#include "Wire.h"
#include "Adafruit_LiquidCrystal.h"
// Connect via i2c, default address #0 (A0-A2 not jumpered)
Adafruit_LiquidCrystal lcd(0);
// Where the temperature sensor probe is connected.
#define ONE_WIRE_BUS 4 //need 4.7k pull-up to stablize data transfer

// Setup a OneWire instance to communicate with any devices.
OneWire oneWire(ONE_WIRE_BUS);

// Pass our oneWire reference to Dallas Temperature.
DallasTemperature sensors(&oneWire);

// define relay pin
int relayPin = 7;

// define motor pin
int motorPin = 6;

// let's add 2 leds to indicate heater status
int ledON = 2; //red one!
int ledOFF = 3; //maybe a green one?

void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600);
  pinMode(relayPin, OUTPUT);
  pinMode(ledON, OUTPUT);
  pinMode(ledOFF, OUTPUT);
  pinMode(motorPin, OUTPUT);
  digitalWrite(relayPin, HIGH);
  sensors.begin(); //start up the thermometer library
    // set up the LCD's number of rows and columns: 
  lcd.begin(16, 2);
  // uncomment this line to save some power
  lcd.setBacklight(LOW);
  // Print a message to the LCD.
  lcd.print("hello!");
}

void loop() {
  
  sensors.requestTemperatures();
  float tempC = sensors.getTempCByIndex(0);
  if (tempC < 29){ // lower bound for turning on the heater
    digitalWrite(relayPin, HIGH);
    analogWrite(motorPin, 63);
    // the motor draws a lot of current, so I pwm'ed it to have just enough amount of turbulance
    lcd.setCursor(0, 0);
    lcd.print("heater on!");
    digitalWrite(ledON, HIGH);
    digitalWrite(ledOFF, LOW);
    delay(100);
  }
  if (tempC >= 31){ // upper bound for turning off the heater
    lcd.setCursor(0, 0);
    digitalWrite(relayPin, LOW);
    digitalWrite(motorPin, LOW);
    lcd.setCursor(0, 0);
    lcd.print("heater off...");
    digitalWrite(ledON, LOW);
    digitalWrite(ledOFF, HIGH);
    delay(100);
  }
  lcd.setCursor(0, 1);
  lcd.print(tempC);
  delay(2000); //read temp only per 2 seconds
}

Demosssss!